@echo off
echo.
if "%1" == "" goto toon_projecten
if "%2" == "save" goto save
if exist c:\projects\%1.sys goto bestaat
if exist c:\projects\%1.bat goto bestaat
echo Het project %1 bestaat niet!
echo.
:toon_projecten
more <c:\projects\projects.txt
echo.
type c:\projects\current.txt
goto end

:bestaat
if not "%2" == "edit" goto noedit
q c:\projects\%1.sys c:\projects\%1.bat c:\projects\%1.inf
echo.
getjn Dit project actief maken
if errorlevel 1 goto copyit
goto end
:noedit
if "%2" == "" goto copyit
echo Usages: project ["pjname" [edit|save]]
goto end
:copyit
if exist c:\projects\%1.inf type c:\projects\%1.inf
del c:\config.sys >nul
if exist c:\projects\%1.sys goto sys_bestaat
echo config.sys  :  default project
copy c:\projects\default.sys c:\config.sys >nul
goto verder
:sys_bestaat
echo config.sys  :  van project %1
copy c:\projects\%1.sys c:\config.sys >nul

:verder
del c:\autoexec.bat >nul
if exist c:\projects\%1.bat goto auto_bestaat
echo autoexec.bat:  default project
copy c:\projects\default.bat c:\autoexec.bat >nul
goto klaar
:auto_bestaat
echo autoexec.bat:  van project %1
copy c:\projects\%1.bat c:\autoexec.bat >nul

:klaar
echo Het huidige project is '%1'. >c:\projects\current.txt
echo.
echo klaar om opnieuw te booten
echo.
getjn zal ik rebooten
if errorlevel 1 be reboot
goto end

:save
if exist c:\projects\%1.sys goto bestaat_al
if exist c:\projects\%1.bat goto bestaat_al
goto saveit
:bestaat_al
echo Het project %1 bestaat al
getjn Overschrijven
if errorlevel 1 goto saveit
goto end
:saveit
echo.
echo config.sys:    naar project %1
copy c:\config.sys c:\projects\%1.sys >nul
echo autoexec.bat   naar project %1
copy c:\autoexec.bat c:\projects\%1.bat >nul

:end