Very short BF interpreter written in BF

Very short BF interpreter written in BF

Of course, it could be expected that someone would come up with a shorter (and much faster) BF interpreter written in BF than the one I wrote. On November 4, 2002, I received the following email from NYYRIKKI:

Hi,

I saw your BrainFuck interpreter for BrainFuck and it encouraged me to write my own version of it. I now write to you as I thought, you might be interested about it.

I wanted to write as fast version as possible so I wrote it directly with Brainfuck. Here is a list of key tricks, that I used to get maximum performance:

I used loader routine, that removes comments before executing and converts BF code to internal format. In the internal format numbers 1-8 are used for commands and zero is used to terminate execution (code before line split) This is because handling small numbers is much more effective than handling large numbers in BF.
I used special IF (x)=0 stucture like this: >+<[>-]>[THEN >] to avoid slow byte copying loops. (Command backup etc.)
I used 3 bytes for each program element to get maximum speed. Using less would have caused program it self get more slow and complex and using more would have slowed down memory seek. For program memory I used 2 bytes for each element.
Data is not transferred between memory and program. In "[" command I only move Z flag. (Value in memory is more likely to be NZ and "0" is faster to move than "1")

This program works same way as yours. Only difference is, that program termination character is ":" instead of "!"

No more explaining... here is the code:

>>>+[,>+++++++[<------>-]<[->+>+<<]>>[-<<+>>]<->+<[>-<[-]]>[-<<[-]++++
+>>>>>]<<[->+>+<<]>>[-<<+>>]<-->+<[>-<[-]]>[-<<[-]++++++++>>>>>]<<[->+
>+<<]>>[-<<+>>]<--->+<[>-<[-]]>[-<<[-]++++++>>>>>]<<[->+>+<<]>>[-<<+>>
]<---->+<[>-<[-]]>[-<<[-]+++++++>>>>>]<<[->+>+<<]>>[-<<+>>]++++++[<---
>-]+<[>-<[-]]>[-<<[-]++++>>>>>]<<[->+>+<<]>>[-<<+>>]+++++[<---->-]+<[>
-<[-]]>[-<<[-]+++>>>>>]<<[->+>+<<]>>[-<<+>>]+++++++[<------->-]+<[>-<[
-]]>[-<<[-]+>>>>>]<<[->+>+<<]>>[-<<+>>]+++++++[<------->-]<-->+<[>-<[-
]]>[-<<[-]++>>>>>]<++++[<---->-]<]<<<[<<<]>>>
[-->+<[>-]>[>]<<++>[-<<<<
<+[>-->+<[>-]>[-<<+>>>]<<+>+<[>-]>[-<<->>>]<<+<[-<<<+>>>]<<<]>>>>>]<->
+<[>-]>[>]<<+>[-<->>>[>>>]>[->+>>+<<<]>[-<+>]>>[-[->>+<<]+>>]+>[->+<]>
[-<+>>>[-]+<<]+>>[-<<->>]<<<<[->>[-<<+>>]<<<<]>>[-<<<<<+>>>>>]<<<<<<<[
>>[-<<<+>>>]<<<<<]+>>[>-->+<[>-]>[-<<->>>]<<+>+<[>-]>[-<<+>>>]<<+<[->>
>+<<<]>>>]<]<--->+<[>-]>[->>[>>>]>+<<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>-<
<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>+<<<]>[-<+>]>>[-[->>+<<]+>>]+>+<
[-<<]<<<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>+<<<]>[-<+>]>>[-[->>+<<]+
>>]+>-<[-<<]<<<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>+<<<]>[-<+>]>>[-[-
>>+<<]+>>]+>.<[-<<]<<<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>+<<<]>[-<+>
]>>[-[->>+<<]+>>]+>,<[-<<]<<<<<[<<<]>>]<<++++++++>>>]

Thanx for giving me inspiration! :-)

~NYYRIKKI

Bit Doubler

But NYYRIKKI decided to make something usefull out of the above BF interpreter in BF. The original BF interpreter was working on an array of bytes (0-255). When the following interpreter is executed on such a BF interpreter, each memory location can hold a word (0-65535). Actually, it will always "square" the capacity of the underlying BF interpreter. Hence its name.

>>>+[,>+++++++[<------>-]<[->+>+<<]>>[-<<+>>]<->+<[>-<[-]]>[-<<[-]+++++
>>>>>]<<[->+>+<<]>>[-<<+NNNNNN>>]NNN<NNNNNNNN-->+<[>-<[-]]>[-<<[-]+++++
+++>>>>>]<<[->+>+<<]>>[-NNNNNNN<<NNN+NNNNNNNN>>]<--->+<[>-<[-]]>[-<<[-]
++++++>>>>>]<<[->+>+<<]>NNN>[NN-<NNN<+>>NN]<---->+<[>-<[-]]>[-<<[-]++++
+++>>>>>]<<[->+>+<<]>>[-NNN<NN<+>NNN>]++NN++++[<--->-]+<[>-<[-]]>[-<<[-
]++++>>>>>]<<[->+>+<<]>>NNNNN[-<<NNN+>>]NN+++++[<---->-]+<[>-<[-]]>[-<<
[-]+++>>>>>]<<[->+>+<<]>NNN>[NN-<NNN<+>>NN]+++++++[<------->-]+<[>-<[-]
]>[-<<[-]+>>>>>]<<[->+>+NNN<<NN]>NNN>[-<NN<+>>]+++++++[<------->-]<-->+
<[>-<[-]]>[-<<[-]++>>>>>NNNNNNN]<NNN++++NN[<---->-]<]<<<[<<<]>>>[-->+<[
>-]>[>]<<++>[-<<<<<+[>--NNNNNN>+<NNN[>-]NN>[-<<+>>>]<<+>+<[>-]>[-<<->>>
]<<+<[-<<<+>>>]<<<]>>>>>]<->+<[>-]>[>]<<+>[-<->>>[>>>]>[->+>>>+<<<<]>[-
<+>]>>>[-[->>>+<<<]+>>>]+>[->>+<<]>>[-<<+>>>>>[-]+<<<]<[->+<]>[-<+>>>>[
-]+<<<NNNNN]+>>>NNNN[-<<NNN<-NNN>>NNNNNN>]<NN<<<<<[NNNNNN->NNNNNN>>[-<<
<+>>>]NNNNNN<<<NNNNNN<<<NNN]>NNN>>NNNNNN[-<NN<<<<<+NNNNNN>>NNNNNNN>>>>]
<<<<<<NN<<NN[>NNN>[-NN<<NNN<+NNN>>NN>]NN<<<NN<<]+>>NN[>-->+NN<[>NN-]>[-
<<->>>NN]<NN<+NN>+<[NN>-NNN]>NNN[-NNNNNN<<+NN>>>]<<NNNNNN+<NN[->NN>>+<<
<]>>>]NN<]NNN<NN--->NN+<NNN[>NNN-]NNNNN>[->NN>[>>>]NNNNNN>+NNNNNN<<<<[<
<<]>>]NN<<NN->NN+<[>NN-]NNN>[NNN->NN>[NNN>>NN>]>-<<NN<<[<<<NNNNNN]>>]<<
->+<[>NN-]NN>[NN->>[NN>>>NN]>NN[->NN+>>NN>+NN<<<<]>NN[-<+>]NN>>NN>[-[->
>>+<<<NNNNNN]+>NN>>NNN]+>NNN[NN-<+NNNNNNN>]NNNNNN>>NNNNNN+<NN<<[NN>>>-]
>>>[>>NNNNN>]<<<NNNNN[-<+>NNNN]<<<NNNNNN[->NNNNNN+<NNNNNN]+NN[-<NN<<]<<
<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>>+<<<<]>[-<+>]>>>[-[->>>+<<<]+>>>
]>[-<+>]>>+<<<[>>>-]>>>[>>>]<<<[-<->]<<<-[->+<]+[-<<<]<<<<<[<<<]>>]<<->
+<[>-]>[->>[>>>][  <-- Made By NYYRIKKI 2002 -->  ]>[->+>>>+<<<<]>[-<+>
]>>>[-[->>>+<<<]+>>>]+>.<[-<<<]<<<<<[<<<]>>]<<->+<[>-]>[->>[>>>]>[->+>>
>+<<<<]>[-<+>]>>>[-[->>>+<<<]+>>>]+>,<[-<<<]<<<<<[<<<]>>]<<++++++++>>>]

(On November 13, 2002, I recieved an email from Daniel B. Cristofani pointing to his even shorter interpreter.)

Brainf***